Ich wollte mal wieder die Hilfe zu bestimmten Themen wie Makros ausbauen. Deshalb Fang ich mal mit „Narecs kleiner Makroecke“ an. Als Einführung zum Thema Mach ich mal ne Auflistung der Makrobefehle, der Optionen und dem ganzen Rest. Als nächstes post ich nützliche Gundmakros für Jedermann und –frau. Danach werde ich einige Klassenmakros zum besten geben. Wenn ihr wollt dürft ihr euch ruhig an dem Thema beteiligen oder Fragen stellen. Bin für alles offen.
Was sind Makros und wie find ich sie?
Makros sind kleine aber feine Teilprogramme die einem helfen komplizierte Aktionen zu vereinfachen, Platz zu sparen in der Aktionsleiste oder einfach nur Zauber mit netten Texten oder Emots auszustatten. Beispiele folgen in den einzelnen Kapiteln. In das Makromenu kommt ihr über 2 Wege, der eine ist das Optionsfenster auf machen und auf Makro klicken, der zweite Weg ist einfacher: [Enter] /m [Enter]
Makroeigenschaften:
Makros bekommen einen Aktionsbutton wie die Zauber aus dem Zauberbuch. Namen kann man selbst eintragen ist, kann aber nur maximal 16 Zeichen haben. Das dazugehörige Bild kann man sich aussuchen (da gibt’s noch Kniffe, dazu später mehr). Makros sind auf 256 Zeichen begrenzt. Ihr könnt 36 Grundmakros und 18 Charaktergebundene Makros anlegen. Es gibt seit Patch 2.0 keine Möglichkeit mehr Buffs, Mana, Lebenspunkte oder ähnliches abzufragen und als Bedingung für ein Makro zu benutzen. Zeitliche Abläufe sind nur eingeschränkt nutzbar und sind an sich nur Abklingzeiten. Makros führen alles wie eingetragen bei benutzen sofort aus. Ein Makro Arbeitet alles von links nach rechts und von oben nach unten ab, es sei den man setzt Bedingungen oder ein Stoppsignal. Schreibt man mehrere Zauber ohne Bedingungen hintereinander wird der erste ausgeführt und die mit der gleichen
Globalen Abklingzeit (GCD = Globel CoolDown) geben Meldung das sie nicht benutzbar sind, weil ein anderer Zauber gerade gewirkt wird oder so, das Übliche eben. Wenn ihr also mehrere Zauber über einen Knopf benutzen wollt braucht, müsst ihr dem System sagen welcher Zauber in welchem Fall benutzt werden soll.
Ich seh jetzt schon bei einigen dir Fragezeichen über dem Kopf und Qualm aus den Ohren steigen
aber an sich ist alles nur halb so schlimm. Ich schätze wenn ihr mal ein paar Makros gesehen habt und wist was sie tun, wird’s einfacher. Also weiter im Text.
Die Makrobefehle:
Es gibt an sich verschiedene Möglichkeiten ein Makro zu schreiben. Die Variante mit der lua-Programmierung über lass ich den Profis mit ihren
/run- und
/script-Befehlen. Ich bin ehrlich, davon versteh ich auch nicht all zu viel. Ich will euch die direkten Befehle näher bringen. Mit ihnen kann man so ziemlich alles abdecken was man braucht. Hier sind die auch schon.
/cast /wirken - Wirkt einen Zauber oder eine Fähigkeit
/dismount /absitzen - Lässt den Spieler vom Reittier absteigen.
/startattack /angriffstart - Startet den Nahkampfangriff.
/stopattack /angriffende - Stoppt den Nahkampfangriff.
/castrandom <Zauber>,<Zauber> /zufälligwirken - Wirkt die angegebenen durch Komma getrennten Zauber zufällig.
/castsequence /sequenzwirken - Wirkt eine Reihe von Zaubern. (Mehr dazu weiter unten)
/stopcasting /stoppwirken - Unterbricht das Zauberwirken.
/cancelaura <Buffnamen> /auraabbruch - Bricht den angegebenen Stärkungszauber ab.
/cancelform /gestaltabbruch - Unterbricht die aktive Gestalt. (z.B. die Formen des Druiden oder die Schattengestalt des Priesters)
/equip <Gegenstand> /anlegen /an - Rüstet den Spieler mit dem angegebenen Gegenstand aus.
/equipslot <#> <Gegenstand> /platzanlegen - Rüstet den Spieler mit dem angegebenen Gegenstand im angegebenen Inventarplatz aus. (Namen und die dazu gehörigen Platznummern folgen weiter unten.)
/use <Gegenstand, Inventarplatz oder Tasche und Taschenplatz oder' item:ItemID'> /benutzen - Benutzt den angegeben Gegenstand, Inventarplatz oder den Gegenstand im Taschenplatz oder eine ItemID.
/userandom <Gegenstand>,<Gegenstand> /zufälligbenutzen - Benutzt die angegebenen durch Komma getrennten Gegenstände zufällig.
/changeactionbar <#> /aktionsleistewechsel - Wechselt die Aktionsleiste auf die angegebene Nummer.
/swapactionbar <#> <#> /aktionsleisteumschalten - Wechselt die Aktionsleiste zwischen den angegebenen Nummern hin und her.
/targetenemy - Nächsten Feind anvisieren.
/targetfriend - Nächsten Freund anvisieren.
/targetparty - Nächstes Gruppenmitglied anvisieren.
/targetraid - Nächstes Schlachtgruppenmitglied anvisieren.
/targetenemyplayer /feindlichenspielerwählen - Nächsten feindlichen Spieler anvisieren
/targetfriendplayer /freundlichenspielerwählen - Nächsten befreundeten Spieler anvisieren
/cleartarget /zielaufheben - Wählt das Ziel ab.
/focus <Einheit> /fokus - Setzt den Fokus auf das Ziel oder die angegeben Einheit.
/clearfocus /fokusaufheben - Wählt den Fokus ab.
/petattack /bangriff - Den Begleiter angreifen lassen.
/petfollow /bfolgen - Den Begleiter zu sich rufen.
/petstay /bbleib - Sitz! Bleib! Gutes Tier, hier hast du eine geröstete Wachtel als Belohnung!
/petpassive /bpassiv - Setzt den Begleitermodus auf passiv.
/petdefensive /bdefensiv - Setzt den Begleitermodus auf defensiv.
/petaggressive /baggressiv - Setzt den Begleitermodus auf aggressiv.
/petautocaston <Zauber> /bautozauberan - Aktiviert für den angegebenen Begleiterzauber das automatische Wirken.
/petautocastoff <Zauber> /bautozauberaus - Deaktiviert für den angegebenen Begleiterzauber das automatische Wirken.
/stopmacro /stopmakro - Unterbricht das Makro.
/click <Interfaceknopf> /klick - Simuliert einen Mausklick auf den angegebenen Interfaceknopf
/target <mobname> /tar /Ziel - Ein bestimmtes Ziel anvisieren
/targetlasttarget /vorherigesziel - Erklärt sich von selbst
/assist /a /unterstützen - Unterstützt das den Anvisierten Spieler und übernimmt dessen Ziel
/run /script <code> - führt einen .lua Code aus. Genaueres müsste ihr euch im Netz erkundigen, außer einer von euch kennt sich aus und übernimmt den Part.
Spezialbefehle:
#show <Zauber> - Im Makro wird der erste Zauber der vorkommt für die Anzeige genutzt. Soll es aber ein anderer Spruch sein, kann man diesen Befehl nutzen.
#showtooltip <Zauber> - Eine Erweiterung von dem normalen #show. Wenn man mit der Maus über dieses Makro fährt, wird zusätzlich der Tooltip des Zaubers angezeigt.
Diese Befehle reagieren auch auf die Bedingungen.
#showcooldown <Zauber> - Zeigt die Cooldown eines Zaubers
%t - schreibt den Namen des Anvisierten Zieles in den Chat wenn man eine Textmakro benutzt. %t kann an jeder Stelle des Textes eingefügt werden.
z.B.
/em Grüßt %t ganz Herzlich
/s Willkommen %t
Alle Makros und Makro-Befehle können mit Bedingungen/Optionen spezifiziert und angepasst werden. Optionsbefehle werden in [ ] hinter den Befehlen und vor den Zauber/Gegenstand gesetzt, hier ein grobes Beispiel:
/wirken [<erste Bedingung/Option>] <erster Zauberspruch>; [<zweite Bedingungen/Option>] <zweiter Zauberspruch>; [<dritte Bedingungen/Option>] <dritter Zauberspruch>Auch hier für hab ich eine Liste:
• help - Trifft zu, wenn der Spieler dem aktuelle Ziel helfen (Heilung, Stärkungszauber...) kann.
• harm - Trifft zu, wenn der Spieler das aktuelle Ziel angreifen kann.
• combat - Trifft zu, wenn der Spieler im Kampf ist.
• stance oder stance:<#> - Trifft zu, wenn der Spieler in einer Haltung oder in der angegebenen ist. (mehr dazu weiter unten)
• stealth - Trifft zu, wenn der Spieler unsichtbar ist.
• modifier oder modifier:shift/ctrl/alt oder kurz mod - Trifft zu, wenn die angegeben Taste während dem Makro gedrückt wird.
• equipped:<Gegenstandstyp oder Inventarplatz> - Trifft zu, wenn der Spieler einen Gegenstand mit dem angegebenen Inventarplatz oder die Gegenstandsart (z.B. Schild oder Nebenhand) ausgerüstet hat. (mehr dazu weiter unten)
• actionbar:<#> - Trifft zu, wenn die aktuelle Aktionsleiste und die angegeben Nummer übereinstimmen.
• pet:<Begleitertyp oder Begleitername> - Trifft zu, wenn der angegebene Begleiter dabei ist. Dies kann ein Typ (Eule, Bär, Wichtel) oder der Name (Bello, Goleo) sein. Ohne spezielle Angabe (also [pet]) trifft es bei jedem anwesenden Begleiter zu.
• mounted, swimming, flying - Trifft zu, wenn der Spieler am Reiten, Schwimmen oder Fliegen ist.
• indoors, outdoors - Trifft zu, wenn sich der Spieler drinnen oder draußen befindet.
• flyable - Trifft zu, wenn der Spieler auf sein fliegendes Reittier aufsteigen kann, also wenn er sich in der Scherbenwelt befindet.
• button:<#> - Trifft zu, wenn der angegeben Mausknopf für das Makro benutzt wurde. (Mehr dazu weiter unten)
• channeling:<Zauber> - Trifft zu, wenn der Spieler den angegeben Zauber kanalisiert. Ohne Zauber (also [channeling]) trifft jeder kanalisierte Spruch zu.
• exist oder exists - Trifft zu, wenn das aktuelle Ziel des Spielers in der Welt existiert.
• dead - Trifft zu, wenn das aktuelle Ziel des Spielers tot ist.
• group oder group:party/raid - Trifft zu, wenn sich der Spieler in einer Gruppe befindet oder in einer der angegebenen. Normale Gruppe: party oder Schlachtzug: raid.
• spec:<#> - Trifft zu wenn eine der beiden Talentspezialisierungen gewählt ist. 1 für die Primäre und 2 für die Sekundäre
• target=<einheit> - Setzt die Einheit für die Bedingungen (die unten mit 'Ziel des Spielers' aufgelistet sind) und Zauber. Mögliche Einheiten:
Zitat:
player - Spieler
target - Ziel (wobei das der Standard ist, wenn man '[target]' nicht benutzt)
targettarget - Ziel des Ziels
pet - Begleiter
focus - Die fokusierte Einheit
party1 - Gruppenmitglied 1
partypet2 – Pet von Gruppenmitglied 2
raid33 - Schlachtzugmitglied 33
raidpet12 - Schlachtzugbegleiter 12
none - Kein Ziel
Noch mehr Möglichkeiten:
- Man kann die Bedingungen auch mit 'no' am Anfang umkehren. Die Bedingung 'nocombat' würde dann nur zutreffen, wenn sich der Spieler nicht im Kampf befindet.
- Mehrere Bedingungen kann man mit einem Komma verbinden. Dieses gilt als 'und' und der Zauber wird nur ausgeführt, wenn alle Bedingungen zutreffen. (Beispiel: [combat,harm])
- Die Parameter der Bedingungen kann man mit einem Schrägstich verbinden. Dieser gilt als 'oder' und der Zauber wird nur ausgeführt, wenn einer davon zutrifft (Beispiel: [stance:1/2]). Ungültig ist '[combat/help]', benutzt statdessen [combat][help].
- Das neue Fragezeichen-Icon im Makrofenster wird durch das Icon des Spruches ersetzt, dass als Informationsquelle dient. (siehe unten '#show' bzw. '#showtooltip')
- Man kann vor Zauber ein ! setzen. Dann wird dieser Zauber nicht wieder benutzt, wenn er aktiviert ist. zB. "/cast !Autoshot". Ohne !: Klick 1 Autoshot an, Klick2 Autoshot aus, Klick 3 Autoshot an... Mit !. Klick 1 Autoshot an. Jeder weitere Klick macht nichts.
So nun komm ich zu den einzelnen Befehlen mit Besondertheiten
Als erstes die Haltungen
/stanceDie Haltungen sind ein besonderer Teil bestimmter Klassen. Wird beim
/stance keine Zahl angegeben, trifft die Bedingung zu, wenn der Spieler in irgendeiner Haltung ist. (Anmerkung: Krieger befinden sich immer in einer von ihren 3 Haltungen)
Jede Klasse hat verschieden viele Haltungen:
Klasse: Druide Krieger Priester Schurke
---------------------------------------------------------------------------------------------------
stance:1 Bär Kampf Schattenform Verstohlen
---------------------------------------------------------------------------------------------------
stance:2 Wasser Verteidigung
---------------------------------------------------------------------------------------------------
stance:3 Katze Berserker
---------------------------------------------------------------------------------------------------
stance:4 Reise
---------------------------------------------------------------------------------------------------
stance:5 Moonkin/Baum
---------------------------------------------------------------------------------------------------
stance:6 Flug
---------------------------------------------------------------------------------------------------
Paladin Auren zählen nicht dazu und können nicht abgefragt werden. Bei Todesritter Präsenzen bin ich mir nicht sicher, schätze aber ebenfalls das sie keine Stance sind. Ihr könnt mich aber gern eines Bessern belehren, wenn ihr euch sicher seit.
Wenn der Spieler eine Haltung auslässt, füllt die nächste ihren Platz. Hat also ein Krieger nie die Verteidigungshaltung abgeholt, ist die Berserkerhaltung die Nummer 2. Das gilt auch für die Druidenformen! Die Flugform ist die 5, wenn ihr keinen Baum oder Moonkin habt.
Ein paar Beispiele:
/wirken [nostance] Bärengestalt
Ist der Spieler in keiner Gestalt, wirkt das Makro Bärengestalt.
/wirken [stance:1] Überwältigen; [stance:2] Rüstung zerreißen; [stance:3] Wirbelwind
Wirkt Überwältigen in der Kampfhaltung, Rüstung zerreißen in der Verteidigungshaltung und Wirbelwind in der Berserkerhaltung.
/wirken [stance:1] Knurren; [stance:3] Klaue
Wirkt Knurren in Bären- und Klaue in Katzengestalt.
/auraabbruch [stance:3] Katzengestalt
Beendet die Katzengestalt, wenn man gerade eine Katze ist.
Angelegte Ausrüstung
-----------------------------
Die '[equipped]' Bedingung funktioniert gleich, hat aber viel mehr Parameter. Wie oben schon erwähnt, kann es ein Inventarplatz oder Gegenstandstyp von einem ausgerüsteten Gegenstand sein.
Hier eine Liste der Inventarplätze (Positionsnummer des Gegenstands):
Kopf (1) Hände (10)
Hals (2) Taille (6)
Schulter (3) Beine (7)
Rücken (15) Füße (8)
Brust (5) Finger (11)
Hemd (4) Finger (12)
Wappenrock (19) Schmuck (13)
Handgelenke (9) Schmuck (14)
Waffenhand (16) Schildhand (17) Relikt/Distanz (18) Munition ()
Taschenplatz 1 (20)
Taschenplatz 2 (21)
Taschenplatz 3 (22)
Taschenplatz 4 (23)
Das geht auch mit einer Gegenstandsart:
Waffe
Einhändig
Zweihändig
Einhandstreitkolben
Stäbe
In Schildhand geführt
Dolch
Stoff
Tasche
usw...
(Auf dieser englischen Seite findet ihr noch mehr Typen: (
http://www.wowwiki.com/ItemType). Bedenkt aber, dass die deutsche World of Warcraft Version nur deutsche Namen akzeptiert, da das Interface auf die lokalisierten Namen zurückgreift. Meistens findet sich die richtige Bezeichnung im Tooltip des Gegenstandes.)
Einige Beispiele:
/wirken [equipped:Zweihandschwerter] Tödlicher Stoß; Heldenhafter Stoß
Dieses Makro wirkt Tödlicher Stoß, wenn der Spieler ein Zweihandschwert anhat, sonst Heldenhafter Stoß.
/wirken [equipped:Zweihandschwerter/Zweihandkolben/Zweihandäxte/Stangenwaffen] Tödlicher Stoß
Tödlicher Stoß wird gewirkt, wenn irgendeine Waffe von diesen Typen ausgerüstet ist.
/wirken [equipped:Schilde] Shildhieb; Zuschlagen
Dieses Makro wird nur Schildhieb wirken, wenn ein Schild ausgerüstet ist, sonst Zuschlagen.
/wirken [equipped:Schilde,equipped:Dolche] Schildschlag
Dieses wird Schildschlag nur wirken, wenn ein Schild und ein Dolch ausgerüstet sind.
Mausklicks
-----------------------------
Mit der Bedingung '[button]' kann man die Maustaste abfragen, mit der auf den Button geklickt wurde. Ohne Angabe wird auf die linke Maustaste geprüft. Wenn man das Makro per Tastaturtaste ausführt, gilt diese als linker Mausklick.
1 für die linke Maustaste
2 für die rechte Maustaste
3 für die mittlere Maustaste (Mouseradtaste im Normalfall)
4 für die vierte Maustaste (meist die Daumentaste links)
5 für die fünfte Maustaste (meist die Daumenteste rechts, falls vorhanden)
..oder einer von den Buttons, die mit einem AddOn durch den SecureStateHeader gesetzt wurden.
/wirken [button:2,target=player] Heilen; [help] Heilen
Heilt ein freundliches Ziel oder den Spieler, wenn das Makro mit der rechten Maustaste angeklickt wurde.
/wirken [button:1] Mondfeuer; [button:2] Mondfeuer(Rang 1)
Ein Linksklick wirkt ein Mondfeuer mit dem höchsten Rang und ein Rechtsklick ein Mondfeuer mit dem Rang 1. Praktisch wenn man nur schnell ein Totem vernichten will.
Neuer Befehl: /sequenzwirken (oder /castsequence)
-----------------------------
Dieser neue Befehl bietet euch die Möglichkeit, eine Reihe von Zauber und Fertigkeiten nacheinander durchzuwirken. Das sieht so aus:
/sequenzwirken [<Optionen/Bedingungen>] reset=<#>/target/combat/alt/shift/ctrl <Zauber1>, <Zauber2>, <Zauber3>
Beim ersten Klick auf das Makro wird der erste Zauber gewirkt, beim zweiten Klick der zweite, usw... am Schluss beginnt die Reihenfolge wieder von vorn. Erreicht die Sequenz einen Spruch der nicht gewirkt werden kann (Abklingzeit, außer Reichweite, ...), wird dieser nicht übersprungen. Als Beispiel: Ein Magier wirkt die Frost Nova loslassen und blinzelt sich dann weg.
/sequenzwirken Frost Nova, Blinzeln
Erster Klick: Frost Nova, zweiter Klick: Blinzeln. Beim nächsten Mal wieder von vorn, da aber Frost Nova noch eine Abklingzeit hat, wartet das Skript diese ab.
Man kann auch Bedingungen für die ganze Sequenz einfügen:
/sequenzwirken [combat] Frost Nova, Blinzeln
So wird die Frostnova nicht verschwendet, wenn man nicht im Kampf ist.
Das ist vielleicht nicht so ganz praktisch. Mit einem Resettimer wird nach einer bestimmten Zeit, die Sequenz zurückgesetzt:
/sequenzwirken reset=24 Frost Nova, Blinzeln
Wurde 24 Sekunden nach der Frostnova nicht geblinzelt, setzt sich die Sequenz wieder zurück. So ist die Frost Nova jederzeit wieder bereit, wenn die Abklingzeit beendet wurde.
Ein anderes Beispiel als Hexenmeister, der seine 3 Schaden-über-Zeit Zauber nacheinander auf das Ziel zaubern will:
/sequenzwirken Verderbnis, Feuerbrand, Fluch der Pein
Wird der Hexenmeister mitten in der Sequenz unterbrochen (der Spieler stirbt oder ein zweiter Gegner gesellt sich dazu) und er wechselt auf ein neues Ziel, kann er mit dem Target- oder Combatreset die Sequenz zurücksetzen.
/sequenzwirken reset=combat/target Verderbnis, Feuerbrand, Fluch der Pein
/sequenzwirken reset=combat/target/shift Verderbnis, Feuerbrand, Fluch der Pein
Dieses Makro erlaubt dem Hexer beim nächsten Klick mit gedrückter Umschalttaste die Sequenz manuell zurückzusetzen.
Oder noch komplexer:
/sequenzwirken [button:1] reset=combat/target/shift Verderbnis, Feuerbrand, Fluch der Pein; [button:2] reset=shift Schattenblitz, Blutsauger; [target=player] reset=60 Dämonenrüstung, Unendlicher Atem, Unsichtbarkeit Entdecken
In diesem Makro sind 3 Sequenzen die sich auch jede für selber zurücksetzen kann. Linksklick die bekannte Schwächungszauber Reihenfolge, Rechtsklick abwechselnd einen Schattenblitz und dann einen Blutsauger, bei allen anderen Klicks bufft er sich selber.
Zusätzlich. Wenn eine Fertigkeit keinen Erfolg hat (verfehlt, parriert, widerstanden...) oder kann sie auf Grund eines Cooldowns nicht benutzt werden, wird diese Fertigkeit solange wiederholt, bis sie Erfolg hat. Wenn ihr also plant mit Castsequence irgendwelche Cooldowns zu überbrücken, tut es nicht. Es wird nicht funktionieren.
Noch eine kleine Makrosammlung die ihr erweitern könnt:
Allgemeine Makros:
---------------
/use [target=player] Schwerer Runenstoffverband
Benutzt einen Runenstoffverband auf den Spieler.
/userandom [nomounted] Reittier1, Reittier2, Reittier3
/dismount [mounted]
Für alle, die sich eine Reittiersammlung angelegt haben und sich nicht entscheiden können welches sie denn nun auspacken.
/userandom [nomounted,flyable] Greif1, Greif2
/userandom [nomounted] Reittier1, Reittier2, Reittier3
/dismount [mounted]
Für alle, die nun auch noch ein fliegendes Reittier in der Reittiersammlung haben.
#showtooltip Albinodrache
/use [nomounted,button:2] Albinodrache; Darnassischer Nachtsäbler
/dismount [mounted]
Mountmakro. Linksklick: Fußmount auswählen, Rechtsklick: Flugmount auswählen. Wenn man schon auf einen Mount ist, wird man immer 100% von absteigen. (Reittiernamen anpassen nicht vergessen)
#showtooltip
/cast [button:1] Sondieren
/cast [button:2] Juwelenschleifen(Großmeister)
/cast [button:3] Verhüttung
Mit Rechtklick kann ich sondieren, mit Linksklick mach ich Juwelenschleifen auf und mit Klick auf die Mouseradtaste öffne ich das Verhüttenfenster.
#showtooltip 14
/use 14
Zeigt das angelegte Schmuckstück in Slot von Schmuckstück 2 und mit einem Klick drauf wird es benutzt, falls das möglich ist. Wenn das Schmuckstück wechselt braucht man keinen Namen zu ändern da nicht, dass Schmuckstück selber sondern der Slot abgefragt wird. Die Slotnummern stehen oben.
/usetalents [spec:1] 2; [spec:2] 1
Neu im Bunde die Makros für das Talentumschalten. Ein Klick auf das Makro ändert die Talentskillung, beim 2. Klick wechselt die Skillung zurück.
/script SetRaidTarget("target",8)
Setzt den Totenschädel über das angewählte Ziel. Welches Zeichen ihr setzten wollt liegt an euch. Einfach die Zahl ändern. 0 ist nichts bis 8 für den Totenschädel.
Krieger Makros:
---------------
/cast [nocombat,stance:1] Sturmangriff; [combat,nostance:3] Berserkerhaltung; [nocombat,nostance:1] Kampfhaltung; [combat,stance:3] Abfangen
Sturmangriff/Abfangen: Benutzt Anstürmen/Abfangen oder wechselt in die richtige Haltung.
/cast [stance:1] <Kampfhaltung Fertigkeit>; [stance:2] <Verteidigungshaltung Fertigkeit>; [stance:3] <Berserkerhaltung Fertigkeit>
Allgemeines Haltungsmakro: Ersetzt die Fertigkeiten und diese werden in der korrekten Haltung gewirkt.
/cast [stance:1] Überwältigen; Kampfhaltung
Überwältigen: Benutzt Überwältigen oder wechselt in die Kampfhaltung, wenn sich der Krieger nicht in dieser befindet.
Magier Makros:
---------------
/cast [nocombat] Pyroschlag; Feuerball
Pyroschlag/Feuerball: Wirkt vor Kampfbeginn den Eröffnungszauber Pyroschlag oder wenn im Kampf den normalen Feuerball.
/cast [target=focus, harm] [] Verwandlung
Wirkt Verwandlung aufs Focus. Falls kein Focus vorhanden ist, wird der Zauber normal gezaubert.
Priester Makros:
---------------
/cast [target=targettarget, help] Gorße Heilung; [help] Große Heilung
Heilt das Ziel oder wenn das ein Gegner ist das Ziel des Ziels.
/wirken [target=player] Machtwort: Schild
Schild direkt auf den Spieler.
#showtooltip
/wirken Auferstehung
/stopmakro [outdoors]
/script s={"Erheb dich, %t","Aufstehen, %t","Schlafen kannst du später, %t","Aufwachen, %t","Lieg nicht so faul rum, %t"}; SendChatMessage(s[math.random(getn(s))],"Yell");
Ein Beleben-"Spam"-Macro. Gespammt wird nur, wenn man innerhalb von gebäuden ist (zu 99% also in einer Instanz).
#showtooltip
/focus [button:2,harm]
/wirken [button:1,target=focus] [] Untote fesseln
/em fesselt %t.
Erweitertes Fesseln. Rechtsklick: Ziel fesseln und merken. linksklick gemerktes Ziel nachfesseln, ohne aktuelles aus den Target zu nehmen.
#showtooltip
/stoppwirken
/cast [target=Player] Machtwort: Schild
Notfallwirken: Schild auf sich selbst (anderer gerade gecastete Spruch wird abgebrochen).
#showtooltip
/stoppwirken
/wirken Psychischer Schrei
Notfallwirken: Fear.
#showtooltip
/stoppwirken
/wirken Verblassen
Notfallwirken: Verblassen.
Jäger Makros:
---------------
/cast [button:2] Aspekt des Affen
/cast [button:4] Aspekt des Rudels
/castsequence !Aspekt der Viper, !Aspekt des Falken
Wechselt beim normalen Klicken immer zwischen den Aspekten des Falken und der Viper. Bei linksklick wird Aspekt des Affen aktiviert und bei Daumentaste 1 wird Aspekt des Rudels aktiv. find es ganz nützlich für schnellen Aspektwechsel, falls mal der blaue Saft aus geht.
/cast [combat] Tier Heilen; [nocombat] Tier füttern
/use [nocombat] <Futter>
Begleiter im Kampf heilen, außerhalb füttern.
#showtooltip
/cast [target=pet,dead] Tier wiederbeleben; [nopet] Tier rufen; [button:1,pet] Tier heilen; [button:2,pet] Tier freigeben
Eine andere Variante, Ist kein Tier da wird es gerufen, ist es Tot wird es belebt, ist es am Leben wird es mit Links geheilt und Rechts freigegeben.
Paladin Makros:
---------------
Verschiedene Segen Makros
/cast [button:2] Segen der Könige; Großer Segen der Könige
/cast [button:2] Segen des Lichts; Großer Segen des Lichts
/cast [button:2] Segen der Macht; Großer Segen der Macht
/cast [button:2] Segen der Rettung; Großer Segen der Rettung
/cast [button:2] Segen des Refugiums; Großer Segen des Refugiums
/cast [button:2] Segen der Weisheit; Großer Segen der Weisheit
Rechtsklick kleine Segen Linksklick große Segen.
/cast [button:1] Streitross beschwören(Beschwören); [button:2] Schlachtross beschwören(Beschwören)
/cast [button:2] Lichtblitz; Heiliges Licht
/wirken [button:2] Untote spüren; Mineraliensuche
/sequenzwirken reset=combat/target Siegel des Kreuzfahrers, Richturteil, Siegel der Rechtschaffenheit
Erst wird Siegel des Kreuzfahrers gecastet, danach Wird das Ziel gerichtet und beim dritten klick wird Siegel der Rechtschaffenheit gecastet...
#showtooltip
/cast [target=targettarget, help] [] Heiliges Licht
Heilt ein das freundliche Ziel, dass der Mob gerade vermöbelt; ein freundliches Ziel oder mich selbst.
Das sollte bei allen Heilzaubern funktionieren.
#showtooltip
/cast [combat]Richturteil; [nocombat]Siegel des Kreuzfahrers
/stopcasting
/cast [combat]Siegel der Rechtschaffenheit
Ist nicht perfekt aber macht was es soll. Bei mehreren Gegnern muss man den SdK manuell nachzaubern.
Schamanen Makros:
---------------
#showtooltip Sturmschlag
/castsequence reset=9 Sturmschlag, Erdschock
Schamanen Sturmschlag/Erschock Sequenz.
Druiden Makros
---------------
#showtooltip [stealth] Anspringen; Krallenhieb
/cast [stealth] Anspringen; Krallenhieb
Wenn der Druide in Katzengestellt schleicht ist Anspringen aktiv, sonst Krallenhieb. Ist für einge Kombinationen gut zu gebrauchen, wie auch für Verheeren und Schreddern.
#showtooltip [stance:1/3]Feenfeuer (Tiergestalt)(); Feenfeuer
/cast [stance:1/3]Feenfeuer (Tiergestalt)(); Feenfeuer
/script SetRaidTarget("target",8)
Der Druide hat an sich 3 Feenfeuer, mit diesem Makro braucht er für alle 3 nur einen Platz. Ist man als Bär oder Katze unterwegs wird Tiergestelltfeenfeuer benutzt sonst das normale. Zusätzlich wird in einer Gruppe das anvisierte Ziel mit dem Totenschädel markiert.
/cast [button:2, target=focus] Anregen; [nobutton:3/4] Anregen
/clearfocus [button:4]
/focus [button:4]
Normal wirkt man Anregen auf das Anvisierte Ziel. Hat man ein Ziel im Fokus wird Anregen darauf gewirkt ohne das Ziel zu wechseln. Um das Ziel in den Fokus zu Packen muss man übrigens einfach nur die Daumentaste drücken und beim erneuten drücken wird der Fokus wieder gelöscht. Sehr zu Empfehlen für Katze im Raid als Manabatterie für einen Raidheiler.
Todesritter Makros
---------------
#showtooltip
/castsequence reset=combat Totenerweckung, Todespakt
Bein ersten Klick kommt der Ghoul beim 2. verschwindet er wieder und der DK heilt sich dank Todespakt. Nach dem Kampf ist der Ghoul wieder zu rufen falls der Timer schon abgelaufen ist.
Schurken Makros
---------------
/script PickupInventoryItem (17)
/script PickupInventoryItem (16)
Wechselt die Waffen zischen Waffenhand und Schildhand sofern es möglich ist. Damit Meucheln mit dem Dolch möglich ist. Sonstige Attacken aber dann mit z.B. dem Schwert das mehr Schaden mach ausgeführt werden können.
Das wars Vorerst, mehr weis ich im Moment nicht. Falls ihr Fragen habt, stellt sie. Wenn ihr Makros habt die nützlich sind, einfach dran hängen.
Bis dann
Euer Narec
